MasCameraDevice.mm

//
//  MasCameraDevice.m
//  MaxstAR
//
//  Created by Kimseunglee on 2017. 11. 23..
//  Copyright © 2017년 Maxst. All rights reserved.
//

#import "MasCameraDevice.h"
#import "CameraDevice.h"
#import "MasMatrixUtil.h"
#include <string>
#include <list>
#import <simd/SIMD.h>

@interface MasCameraDevice()
{
    maxstAR::CameraDevice *cameraDevice;
}

@end

@implementation MasCameraDevice

- (instancetype)init {
    self = [super init];
    if (self) {
        cameraDevice = maxstAR::CameraDevice::getInstance();
    }
    return self;
}

- (MasResultCode) start:(int) cameraId width:(int) width height:(int) height {
    return (MasResultCode)cameraDevice->start(cameraId, width, height);
}
- (void) stop {
    cameraDevice->stop();
}
- (int) getWidth {
    return cameraDevice->getWidth();
}
- (int) getHeight {
    return cameraDevice->getHeight();
}
- (bool) setFocusMode:(MasFocusMode) mode {
    return cameraDevice->setFocusMode((maxstAR::CameraDevice::FocusMode)mode);
}
- (bool) setFlashLightMode:(bool) toggle {
    return cameraDevice->setFlashLightMode(toggle);
}
- (bool) setAutoWhiteBalanceLock:(bool) toggle {
    return cameraDevice->setAutoWhiteBalanceLock(toggle);
}
- (void) flipVideo:(MasFlipDirection) direction toggle:(bool) toggle {
    cameraDevice->flipVideo((maxstAR::CameraDevice::FlipDirection)direction, toggle);
}

- (NSMutableArray*) getParamList {
    NSMutableArray *returnArray = [[NSMutableArray alloc] init];
    std::list<std::string> paramlist = cameraDevice->getParamList();
    for (std::string eachParam : paramlist) {
        NSString *eachNSString = [NSString stringWithCString:eachParam.c_str() encoding:NSUTF8StringEncoding];
        [returnArray addObject:eachNSString];
    }
    
    return returnArray;
}
- (bool) setParam:(NSString*) key toggle:(bool) toggle {
    std::string keyString = std::string([key UTF8String]);
    return cameraDevice->setParam(keyString, toggle);
}
- (bool) setParam:(NSString*) key value:(int) value {
    std::string keyString = std::string([key UTF8String]);
    return cameraDevice->setParam(keyString, value);
}
- (bool) setParam:(NSString*) key min:(int) min max:(int) max {
    std::string keyString = std::string([key UTF8String]);
    return cameraDevice->setParam(keyString, min, max);
}
- (bool) setParam:(NSString*) key valueString:(NSString*) value {
    std::string keyString = std::string([key UTF8String]);
    std::string valueString = std::string([value UTF8String]);
    return cameraDevice->setParam(keyString, valueString);
}
- (void) setNewFrame:(Byte *) data length:(int) length width:(int) width height:(int) height format:(MasColorFormat) format {
    cameraDevice->setNewFrame(data, length, width, height, (maxstAR::ColorFormat)format);
}
- (matrix_float4x4) getProjectionMatrix {
    matrix_float4x4 returnMatrix = [MasMatrixUtil makeMatrix:(float*)cameraDevice->getProjectionMatrix()];
    return returnMatrix;
}
- (matrix_float4x4) getBackgroundPlaneProjectionMatrix {
    matrix_float4x4 returnMatrix = [MasMatrixUtil makeMatrix:(float*)cameraDevice->getBackgroundPlaneProjectionMatrix()];
    return returnMatrix;
}

@end